¶ Bluetooth Scanner
¶ Cablage
¶ SoftwareSerial.h Restriction
Attention SoftwareSerial doit être configuré sur des ports interruptibles
NANO: RX: 10, 11, 12, 13
MICRO: RX: 8, 9, 10, 11, 14 (MISO), 15 (SCK), 16 (MOSI).
UNO: RX: 10, 11, 12, 13
MEGE2650: RX: 10, 11, 12, 13, 14, 15, 50, 51, 52, 53, A8 (62), A9 (63), A10 (64), A11 (65), A12 (66), A13 (67), A14 (68), A15 (69).
¶ Code
// HC-05 HC-03 OK Vcc=3,3V Mandatory
// JDY-31 OK
// HC-06 Non configurable 9600 Code:1234
//
// Attention SoftwareSerial pose des pb sur Méga2560
#define BaudTabSize 14
#define RESET false
#define BT_EN 8
#define VCC 9
#define GND 10
#define BT_TX 11
#define BT_RX 12
#define BT_STATE 13
#include <SoftwareSerial.h>
SoftwareSerial BTserial(BT_TX, BT_RX);
unsigned long bauds[BaudTabSize] = {300, 1200, 2400, 4800, 9600, 19200, 38400, 57600, 74880, 115200, 230400, 460800, 921600, 1382400 };
long BTBAUD=38400;
long SERIALBAUD=9600;
String msg;
String BT_answer = "";
bool match = false;
void setup(){
pinMode(BT_STATE,INPUT);
pinMode(VCC,OUTPUT);
pinMode(GND,OUTPUT);
pinMode(BT_TX,INPUT);
pinMode(BT_RX,OUTPUT);
pinMode(BT_EN,OUTPUT); // Enable / Key
digitalWrite(VCC, HIGH);
digitalWrite(GND, LOW);
digitalWrite(BT_EN, HIGH);
Serial.begin(SERIALBAUD);
Serial.println("Hello Bluetooth scanner !");
Serial.println("=========================");
Serial.println("> Slow blinking => AT mode (Enable to VCC)");
Serial.println("> Fast blinking => data mode (Enable to GND)");
Serial.println(" ");
Serial.println("");
if (!BT_Scan()) {
Serial.println("!!! Fallback "+String(BTBAUD)+" baud !!!");
BTserial.begin(BTBAUD);
}
Serial.println("ENTER AT Commands:");
digitalWrite(BT_EN, LOW);
}
void loop(){
readSerialPort();
if(msg!="") {
BTserial.println(msg);
delay(500);
}
if (BTserial.available()>0){
Serial.write(BTserial.read());
}
}
void readSerialPort(){
msg="";
while (Serial.available()) {
delay(10);
if (Serial.available() >0) {
char c = Serial.read();
msg += c;
}
}
if ( msg == "test?" ) {
readAnyBT();
} else if ( msg == "scan?" ) {
BT_Scan();
} else if ( msg.substring(0,5) == "speed" ) {
BTBAUD = msg.substring(5).toInt();
Serial.println("!!! Fallback "+String(BTBAUD)+" baud !!!");
BTserial.begin(BTBAUD);
} else if ( msg != "" ) {
Serial.println(msg);
}
}
void readHC06() {
BTserial.begin(BTBAUD);
Serial.println("");
Serial.print("Dump Bluetooth module HC-06 like - ");
Serial.println(BTBAUD);
sendCommand("AT+NAME", true);
sendCommand("AT+VERSION", true);
Serial.println("0:Slave 1:Master 2:Slave-loop ");
sendCommand("AT+ROLE", true);
sendCommand("AT+UART", true);
sendCommand("AT+ADDR", true);
sendCommand("AT+PSWD", true);
}
void readHC05() {
BTserial.begin(BTBAUD);
Serial.println("");
Serial.print("Dump Bluetooth module HC-03 HC-05 like - ");
Serial.println(BTBAUD);
if (RESET) {
String newAddr = sendCommand("AT+ADDR", false);
newAddr = "AT+NAME=HC-05-" + newAddr.substring(16, 20);
sendCommand(newAddr, false);
sendCommand("AT+UART=38400,0,0", false);
sendCommand("AT+PSWD=1234", false);
}
sendCommand("AT+NAME", true);
sendCommand("AT+VERSION", true);
Serial.println("0:Slave 1:Master 2:Slave-loop ");
sendCommand("AT+ROLE", true);
sendCommand("AT+UART", true);
sendCommand("AT+ADDR", true);
sendCommand("AT+PSWD", true);
Serial.println("Reset usine: AT+ORGL ");
}
void readAnyBT() {
BTserial.begin(BTBAUD);
Serial.println("");
Serial.print("Dump unknown Bluetooth module - ");
Serial.println(BTBAUD);
// sendCommand("AT+VERSION\n\r", true);
sendCommand("AT", true);
sendCommand("AT+NAME", true);
sendCommand("AT+NAME?", true);
sendCommand("AT+VERSION", true);
sendCommand("AT+VERSION?", true);
sendCommand("AT+ROLE", true);
sendCommand("AT+ROLE?", true);
sendCommand("AT+BAUD", true);
sendCommand("AT+BAUD?", true);
sendCommand("AT+UART", true);
sendCommand("AT+UART?", true);
sendCommand("AT+LADDR", true);
sendCommand("AT+LADDR?", true);
sendCommand("AT+ADDR", true);
sendCommand("AT+ADDR?", true);
sendCommand("AT+PSWD", true);
sendCommand("AT+PSWD?", true);
sendCommand("AT+PIN", true);
sendCommand("AT+PIN?", true);
sendCommand("AT+STATE", true);
sendCommand("AT+STATE?", true);
}
void readJDY31() {
BTserial.begin(BTBAUD);
Serial.println("");
Serial.print("Dump Bluetooth module JDY-31 like - ");
Serial.println(BTBAUD);
if (RESET) {
String newAddr = sendCommand("AT+LADDR", false);
newAddr = "AT+NAMEJDY-31-SPP-" + newAddr.substring(newAddr.length()-6, newAddr.length()-2);
Serial.println(newAddr);
sendCommand(newAddr, false);
sendCommand("AT+BAUD6", false);
sendCommand("AT+PIN1234", false);
}
sendCommand("AT+NAME", true);
sendCommand("AT+VERSION", true);
Serial.println("4:9600 5:19200 6:38400 7:57600 8:115200 9:128000");
sendCommand("AT+BAUD", true);
sendCommand("AT+LADDR", true);
sendCommand("AT+PIN", true);
Serial.println("/!\\ Restart module to set values... /!\\");
}
bool BT_Scan() {
bool identified = false;
delay(100);
Serial.println(">>>> BT module start scan !");
delay(100);
if ( digitalRead(BT_STATE) == LOW ) {
Serial.println(">> BT not connected !");
for (int i = 0; i < BaudTabSize; i++) {
BTserial.begin(bauds[i]);
Serial.println("[ Test Speed = "+String(bauds[i])+" baud ]");
BT_answer = sendCommand("AT", false);
if ( BT_answer != "" ) {
match = true;
} else {
BT_answer = sendCommand("AT+VERSION", false);
if ( BT_answer != "" ) {
match = true;
} else {
BT_answer = sendCommand("AT+VERSION?", false);
if ( BT_answer != "" ) {
match = true;
}
}
}
if (match) {
Serial.println(BT_answer);
Serial.print(" success ");
Serial.println(bauds[i]);
BTBAUD=bauds[i];
if( BT_answer.substring(0,2) == "OK" || BT_answer.substring(0,5) == "ERROR" ) {
identified = true;
readHC05();
}
if( BT_answer.substring(0,8) == "VERSION:" || BT_answer.substring(0,9) == "+VERSION:" ) {
identified = true;
readHC06();
}
if( BT_answer.substring(0,9) == "+VERSION=" ) {
identified = true;
readJDY31();
}
if( identified == false ) {
readAnyBT();
}
i = BaudTabSize+1;
}
}
} else {
Serial.println(">> BT connected !");
}
Serial.println("<<<< BT module end scan !");
if (match) {
return true;
} else {
return false;
}
}
String sendCommand(const String command, bool echo) {
if (echo) {
Serial.println(">> ["+command+"] ");
}
BTserial.println(command);
delay(500);
char reply[128];
int i = 0;
while (BTserial.available()>0) {
// Serial.write(BTserial.read());
reply[i] = BTserial.read();
i += 1;
delay(10);
}
reply[i] = '\0';
if( echo ) {
Serial.println(reply);
}
delay(100);
return reply;
}
¶ Bluetooth Serial Terminal
Android Bluetooth Terminal HC_05
Windows Bluetooth serial Terminal
¶ Informations
Les modules Bluetooth existent en différentes versions constructeur et différentes éditions. Il devient alors délicat de produire un programme général de détection de module. Les commandes AT disponibles peuvent varier d'une édition à l'autre ainsi que d'un fabriquant à l'autre...
Certains fournisseurs, Elegoo, Keyes,... produise des modules Bluetooth (4 broches) en version spécifiques HC-06. Ces modules contiennent des firmwares spécifiques qui les rend non configurables.
Le mode 'Slave' est idéal pour se connecter à un smartphone ou à un ordinateur. Le mode 'Master' permet de connecter des 'Slave' dans le cas de systèmes plus complexes et autonomes.